Calcul âge Excel

Comment calculer l’âge sur Excel à partir de la date de naissance ?

Pour calculer l’âge d’une personne à partir de sa date de naissance, la solution la plus simple utilise la fonction DATEDIF et la fonction AUJOURDHUI. La syntaxe est la suivante :

=DATEDIF( date_de_naissance ; AUJOURDHUI() ; “Y” )

Cette formule va calculer en temps réel l’âge de la personne. Si la date de naissance est contenue dans une des feuilles de votre classeur Excel, il suffira de sélectionner la cellule.

=DATEDIF( A1 ; AUJOURDHUI() ; “Y” )
--> A1 contient la date de naissance de la personne

Pour calculer l’âge dans Excel à partir d’une autre date que celle du jour, il vous suffit de remplacer la fonction AUJOURDHUI par la date voulue. Je vous conseille pour cela de vous servir de la fonction DATE. Vous pouvez mettre une date dans le passé ou une date dans le futur.

=DATEDIF( date_de_naissance ; DATE(2023;12;01) ; “Y” )

Un exemple du calcul de l’âge sur Excel est disponible en téléchargement vient l’encart ci-dessous.

Explication de la formule

La fonction DATEDIF renvoie la différence entre deux dates en années, mois ou jours.

Pour fonctionner, cette fonction a besoin de 3 arguments :

• date_début – il s’agit de la date initiale à partir de laquelle nous voulons compter. Ici, ce sera la date de naissance de la personne.
• date_fin – il s’agit de la date jusqu’à laquelle nous devons compter. Dans la majorité des cas, il s’agira de la date du jour.
• unité – il s’agit de l’unité de temps dans laquelle nous voulons exprimer la différence. Il pourra s’agir d’années, de mois ou de jours.

Il existe différentes unités de temps pour la fonction DATEDIF. Le tableau suivant indique l’orthographe de chaque unité et le calcul qu’elle provoque dans la formule.

Unité	Explication
Y	Compte le nombre d'années complètes
M	Compte le nombre de mois complets
D	Compte le nombre de jours complets
MD	Compte le nombre de jours passés depuis le dernier mois révolu
YM	Compte le nombre de mois depuis la dernière année révolue
YD	Compte le nombre de jours depuis la dernière année révolue

Les formules ci-dessous calculent la différence entre deux dates. La date de début est le 01/01/2022. La date de fin est le 30/06/2023. Observez bien les différences entre les résultats suivant l’unité de temps saisie dans la fonction DATEDIF.

=DATEDIF(B3;C3;"Y") 
--> 1 année complète

=DATEDIF(B4;C4;"M") 
--> 17 mois complets

=DATEDIF(B5;C5;"D") 
--> 545 jours complets

=DATEDIF(B6;C6;"MD")
--> 29 jours complets depuis le dernier mois révolu
 
=DATEDIF(B7;C7;"YM")

--> 5 mois complets depuis la dernière année révolue

=DATEDIF(B8;C8;"YD")
--> 180 jours complets depuis la dernière année révolue

Calculer l’âge en années et mois

Pour obtenir l’âge en année et mois, il faut saisir dans votre cellule Excel la formule suivante :

= DATEDIF(date_de_naissance ; AUJOURDHUI() ; “Y”) 
& “ ans et “ 
& DATEDIF(date_de_naissance ; AUJOURDHUI() ; “YM”) 
& “ mois”

Vous pouvez recopier directement cette formule Excel dans votre barre de formule et adapter le contenu de la cellule en remplaçant la date de naissance par une formule ou en cliquant sur la valeur. 

Le résultat obtenu  dans votre fichier Excel sera de la forme : 42 ans et 5 mois.

Si vous souhaitez calculer l’âge sur Excel par rapport à une date précise, vous pouvez remplacer la fonction AUJOURDHUI par la date voulue en vous servant de la fonction DATE.

= DATEDIF(date_de_naissance ; DATE(2023;12;01) ; “Y”) 
& “ ans et “ 
& DATEDIF(date_de_naissance ; DATE(2023;12;01) ; “YM”) 
& “ mois”

N’oubliez pas de saisir les guillemets dans votre barre de formule au risque que Microsoft Excel ne comprenne pas votre intention.

Dans notre exemple, la fonction va calculer deux valeurs :

=DATEDIF( DATE(1980;1;1) ; DATE(2022;6;6) ; « Y » )
--> 42 années révolues

=DATEDIF( DATE(1980;1;1) ; DATE(2022;6;6) ; « YM » )
--> 5 mois révolus depuis la dernière année révolue 

Dans la formule de calcul, il suffira de lier ces valeurs grâce au caractère & comme dans la formule suivante :

= 42 & “ ans et “ & 5 & “ mois”

Calculer l’âge en années, mois et jours

Pour obtenir un calcul de l’âge en années, mois et jours, la formule Excel à saisir dans votre cellule est la suivante :

= DATEDIF(date_de_naissance ; AUJOURDHUI() ; “Y”) 
& “ ans, “ 
& DATEDIF(date_de_naissance ; AUJOURDHUI() ; “YM”) 
& “ mois et ” 
& DATEDIF(date_de_naissance ; AUJOURDHUI() ; “MD”) 
& “ jours”

Une nouvelle fois, nous mettons en pratique la formule DATEDIF. Cette fonction avancée nous permet ici à tour de rôle d’obtenir le nombre d’années écoulées, le nombre de mois écoulés depuis la dernière date d’anniversaire, le nombre de jours depuis le dernier mois révolu.

Calcul de l’âge sur Excel avec TRONQUE et FRACTION.ANNEE

On peut également calculer l’âge sur Excel grâce à la fonction TRONQUE, la fonction FRACTION.ANNEE et la fonction AUJOURDHUI. La syntaxe est la suivante :

=TRONQUE( FRACTION.ANNEE( date_de_naissance ;  AUJOURDHUI() ; 3 ) ; 0 )

La fonction Excel FRACTION.ANNEE fait partie des fonctions avancées. Elle calcule le nombre d’années s’étant écoulées entre des dates contenues dans plusieurs cellules. A la différence de la formule Excel DATEDIF, elle ne calcule pas le nombre d’années révolues depuis la date de naissance. Elle mesure le nombre d’années révolues ainsi que la fraction de la nouvelle année entamée. 

La syntaxe de la fonction FRACTION.ANNEE est la suivante :

=FRACTION.ANNEE(date_début; date_fin; "base")

L’argument base permet de choisir la méthode de calcul. Microsoft Excel propose 4 calculs possibles :

• 0 – Etats-Unis – 30/360
• 1 – Réel/réel
• 2 – Réel/360
• 3 – Réel/365
• 4 – Europe – 30/360

Dans notre cas, le calcul choisi n’a pas d’impact puisque nous ne souhaitons pas garder la partie à droite de la virgule. Par contre, si vous venez à réutiliser cette fonction Excel, je vous conseille le « Réel/réel » ou « 30/360 ».

La fonction Excel TRONQUE va permettre de réduire le résultat aux chiffres avant la virgule. La synthase de la fonction est la suivante :

=TRONQUE( calcul ; nb de chiffres après la virgule )

Le dernier paramètre est facultatif. Si nous le laissons vide, Microsoft Excel comprend que nous ne souhaitons pas avoir de chiffres derrière la virgule.

En reprenant notre exemple :

La méthode à ne surtout pas utiliser ! 😱

Il y a une formule Excel à ne surtout pas mettre dans vos tableurs pour calculer l’âge d’une personne. Quand on vous parle de calculer l’âge des personnes dans une plage de données, la plupart des individus pensent avoir la réponse. Même si cette méthode peut sembler juste au premier coup d’œil, elle ne l’est pas. Il faut absolument la bannir au risque de vous retrouver avec des reportings erronés.

Le calcul que la plupart des personnes vous proposeront d’utiliser est la formule suivante :

(date_du_jour - date_de_naissance) / 365

Intégrez-la dans votre feuille de calcul Excel et vous pourrez être sûr(e) de vous retrouver avec des anomalies. Je vous déconseille de copier la formule et de l’appliquer.

Cette formule est fausse. Une année ne compte pas forcément 365 jours et plus la personne sera âgée, plus le résultat sera aberrant.

Dans notre exemple, j’ai plusieurs cellules. Dans les premières j’ai intégré une date de naissance (01/01/1980). Le contenu des autres cellules sont des dates du jour. En utilisant la fonction conseillée, je me retrouve avec une valeur de cellule indiquant qu’un individu né le 1er Janvier fêtant son anniversaire le 21 Décembre. Pas très logique…

Conclusion

Vous savez maintenant comment calculer l’âge sur Excel de différentes manières. 

Nous avons vu :

• comment calculer l’âge sur Excel avec la fonction DATEDIF
• mesurer l’âge d’une personne à partir de sa date d’anniversaire avec FRACTION.ANNEE
• effectuer un calcul de l’âge en années et mois
• saisir dans votre barre de formules différentes fonctions Excel afin d’obtenir l’âge en années, mois et jours

La formule Excel DATEDIF faisant partie des fonctions avancées de Microsoft Excel, elle est cachée (absente du ruban).