Fonction SOMME.SI.ENS

La fonction SOMME.SI.ENS est une fonction Excel permettant d’additionner des cellules qui remplissent une ou plusieurs conditions. Ces conditions peuvent s’appliquer sur du texte, des dates, des nombres. Cette fonction permet les recherches partielles (ex : cellule commençant par).

Article mis à jour le 09/06/2023

Syntaxe

La fonction SOMME.SI.ENS s’écrit de la façon suivante :

= SOMME.SI.ENS( plage_somme ; plage_critère1 ; critères1 ; ... )

Cette fonction possède au minimum trois arguments.

plage_somme – Sélection de cellules à additionner.
plage_critère1 – Sélection de cellules qui doivent répondre au critère.
critères1 – Critère à appliquer. Il peut s’agir d’un critère de date, de nombre ou de texte.
[plage_critère2] – Argument optionnel. Sélection de cellules sur lesquels appliquer un second critère.
[critères2] – Argument optionnel. Second critère à appliquer.

La fonction SOMME.SI.ENS additionne une plage de cellules en appliquant un ou plusieurs critères. Cette fonction permet l’utilisation des opérateurs logiques (>,<,<>,=) et des caractères génériques (*, ?). Ces derniers permettront l’utilisation de critères avancés (ex: cellule commençant par).

Les critères définis peuvent s’appliquer sur :

Des dates ;
Du texte ;
Des nombres.

= SOMME.SI.ENS( B1:B10 ; A1:A10 ; "chaise")
--> 1 critère sur du texte

= SOMME.SI.ENS( B1:B10 ; A1:A10 ; ">100")
--> 1 critère sur un nombre

= SOMME.SI.ENS( B1:B10 ; A1:A10 ; "<>01/01/2023")
--> 1 critère sur une date

L’avantage de la fonction SOMME.SI.ENS est de pouvoir indiquer autant de critères que nous souhaitons. Il suffit alors de saisir tour à tour la plage de cellules sur laquelle appliquer le critère puis le critère.

= SOMME.SI.ENS( 
    B1:B10 ;    --> cellules à additionner
    A1:A10 ;    --> plage avec critère 1
    "chaise" ;  --> critère 1
    C1:C10 ;    --> plage de critère 2
    100.        --> critère 2
  )

Comment utiliser la fonction SOMME.SI.ENS ?

La fonction SOMME.SI.ENS a au minimum 3 arguments. Le premier permet de saisir la plage à additionner. Le second argument est la première plage sur laquelle appliquer un critère. Le 3e argument est le critère à appliquer. Il faudra utiliser des opérateurs logiques et potentiellement des caractères génériques. Pour ajouter d’autres critères, il faudra saisir plage de critère et critère à nouveau.

Les critères

La fonction SOMME.SI.ENS permet l’utilisation des opérateurs logiques (<, >, <>, <=, >=) et des caractères génériques (*, ?). Pour cela, il faut appliquer une syntaxe particulière. Le tableau suivant résume les différents critères applicables suivant le format de la valeur (nombre, texte, date).

Format	Critère	Syntaxe
Numérique	Valeur égale à 10	10
	Valeur supérieure à 10	">10"
	Valeur inférieure à 10	"<10"
	Valeur supérieure ou égale à 10	">=10"
	Valeur inférieure ou égale à 10	"<=10"
	Valeur différente de 10	"<>10"
Date	Valeur égale au 01/01/2023	"01/01/2023"
	Valeur supérieure au 01/01/2023	">01/01/2023"
	Valeur inférieure à au 01/01/2023	"<01/01/2023"
	Valeur supérieure ou égale au 01/01/2023	">=01/01/2023"
	Valeur inférieure ou égale au 01/01/2023	"<=01/01/2023"
	Valeur différente du 01/01/2023	"<>01/01/2023"
Texte	Valeur égale à "Cleex"	"Cleex"
	Valeur différente de "Cleex"	"<>Cleex"
	Valeur commençant par "Cl"	"Cl*"
	Valeur se terminant par "ex"	"*ex"
	Valeur contenant "ee"	"ee"
	Valeur au format xxx-xxx	"???-???"
Autres	Valeur nulle (peut être le résultat d’une formule)	""
	Cellule vide (pas de formule ni de valeur nulle)	"="
	Cellule non vide	"<>"
Date ou num.	Valeur égale à A1	A1
	Valeur supérieure à A1	">"&A1
	Valeur inférieure à A1	"<"&A1
	Valeur supérieure ou égale à A1	">="&A1
	Valeur inférieure ou égale à A1	"<="&A1
	Valeur différente de A1	"<>"&A1

Quelques utilisations de la fonction SOMME.SI.ENS

Additionner les valeurs suivant leurs valeurs

Dans ce premier exemple, nous allons voir comment additionner une plage de cellules selon un critère appliqué sur elle-même. Le critère sera donc forcément numérique.

= SOMME.SI.ENS( A1:A10 ; A1:A10 ; 10 ) --> Valeurs égales à 10
= SOMME.SI.ENS( A1:A10 ; A1:A10 ; ">10" ) --> Valeurs supérieures à 10
= SOMME.SI.ENS( A1:A10 ; A1:A10 ; "<10" ) --> Valeurs inférieures à 10
= SOMME.SI.ENS( A1:A10 ; A1:A10 ; "<>10" ) --> Valeurs différentes de à 10

Additionner des valeurs suivant les valeurs des cellules adjacentes

Si nous prenons l’exemple en en-tête d’article, nous avons une liste d’articles. Nous allons calculer les quantités suivant des critères en lien avec : des nombres, des dates, du texte.

Critères sur des nombres

Pour calculer la somme d’une plage de cellules suivant l’application d’un critère numérique sur une autre plage, inspirez-vous des exemples suivants :

= SOMME.SI.ENS( D3:D14 ; C3:C14 ; ">150" ) --> prix égal à 150

Critères sur des dates

Pour calculer la somme d’une plage de cellules suivant l’application d’un critère au format date sur une autre plage, inspirez-vous des exemples suivants :

= SOMME.SI.ENS( D3:D14 ; E3:E14 ; "<>08/01/2023" )
--> date différente du 08/01/2023

Critères sur des textes

Pour calculer la somme d’une plage de cellules suivant l’application d’un critère au format texte sur une autre plage, inspirez-vous des exemples suivants :

= SOMME.SI.ENS( D3:D14 ; B3:B14 ; "chaise" )
--> si cellule est égale à "chaise"

Critères sur des textes partiels

La fonction SOMME.SI.ENS permet de faire des recherches partielles sur du texte. Ainsi nous pouvons mettre des critères tels que « commençant par », « se terminant par », « contenant », « ne contenant pas ». Voici quelques exemples de l’utilisation de caractères génériques.

= SOMME.SI.ENS( D3:D14 ; B3:B14 ; "*bureau*" )
--> cellule contenant "bureau"

Critères contenus dans d’autres cellules

Il est possible de faire appel à une cellule contenant le critère désiré. Pour cela, il faudra se servir du caractère & pour joindre les opérateurs logiques et/ou les caractères génériques avec la cellule.

= SOMME.SI.ENS( D3:D14 ; C3:C14 ; ">" & A1 )
= SOMME.SI.ENS( D3:D14 ; B3:B14 ; "<>" & A1 )
= SOMME.SI.ENS( D3:D14 ; B3:B14 ; "*" & A1 & "*" )

Gérer les cellules vides et non vides

Par une syntaxe particulière ( « », « <> », « = ») il est possible d’indiquer des critères en lien avec les cellules vides ou non vides.

= SOMME.SI.ENS( D3:D14 ; B3:B14 ; "" ) 
--> si cellule vide
    mais pouvant contenir une formule renvoyant
    un résultat nul

= SOMME.SI.ENS( D3:D14 ; B3:B14 ; "<>" )
--> si cellule non vide

= SOMME.SI.ENS( D3:D14 ; B3:B14 ; "=" )
--> si cellule vide (ne contient rien)

Appliquer plusieurs critères avec logique ET

Comme dans l’exemple présenté en en-tête d’article, on peut cumuler les critères. Voici un exemple :

= SOMME.SI.ENS(
    D3:D14 ;         plage à additionner
    B3:B14 ;         plage critère 1
    "chaise" ;       critère 1
    C3:C14 ;         plage critère 2
    ">150" ;         critère 2
    D3:D14 ;         plage critère 3
    "<160" ;         critère 3
    E3:E14 ;         plage critère 4
    "<>08/01/2023"   critère 4
  )

Appliquer plusieurs critères avec logique OU

Il arrivera que vous vouliez plusieurs possibilités lors de la saisie d’un critère dans votre fonction SOMME.SI.ENS. Par exemple, nous pouvons vouloir les « chaises » ou « bureaux ». Pour cela, vous avez deux solutions.

La première consiste à cumuler plusieurs fonctions SOMME.SI.ENS :

= SOMME.SI.ENS( D3:D14 ; B3:B14 ; "chaise" )
+ SOMME.SI.ENS( D3:D14 ; B3:B14 ; "bureau" )

L’autre solution est plus technique et requiert une syntaxe particulière :

= SOMME( SOMME.SI.ENS( D3:D14 ; B3:B14 ; { "chaise" ; "bureau" } )

Caractéristique de la fonction SOMME.SI.ENS

La fonction SOMME.SI.ENS permet d’additionner des valeurs suivant une ou plusieurs conditions sur les cellules additionnées ou des cellules adjacentes ;
Il faudra mettre les critères entre guillemets dès qu’il s’agira de texte ou qu’il y aura des opérateurs logiques ;
Il faudra lier l’opérateur logique et ses guillemets et la cellule contenant le critère grâce au caractère & ;
La fonction SOMME.SI.ENS supporte les recherches partielles grâce aux caractères génériques (*, ?).

4.9/5 - (22 votes)

Vous avez apprécié cet article ?

Pour me soutenir, cliquez sur cette publicité. Pas besoin d’acheter, un clic suffit.

Merci. 🤩

Annonces

Yann

Créateur de Cleex, ancien contrôleur de gestion dans l’industrie, j’ai à coeur de vous proposer des ressources de qualité pour vous aider à travailler avec Excel.